ShocKNetworK.COM

Sendmail routing through Microsoft Active Directory

To give credit where credit is due, the attachment was sent to me from Randy Fox from csgsystems. There's one bug with public folders. The workaround is to create a mailing list by the same name and make the public folder a member of the list.

If you're reading this, you are probably running a Microsoft Exchange
Server or probably currently already have sendmail relaying to an Exchange
Server and want to improve your setup.

Most sendmail to exchange setups will take mail and blindly relay the mail
over. If yours is like this, you will know that you get email bounces that
can go nowhere because most of the initial intentions of the emails were
for spam and they would just send messages to users that they don't know
even exist. A major problem with this is that it will hold up your sendmail
queue and hinder your performance as it will try to send these emails just
as much as the ones that are important and need to be sent out immediately.
This article will show you how to use sendmail's ldap features to look into
the Active Directory to see where the mail should go and have sendmail send
it there. By having sendmail look into the Active Directory, it will know
whether users exist and will stop immediately after the “RCPT TO” in the
envelope if users don't exist, eliminating the useless, bounce emails that
never get anywhere.

This procedure is not fully supported by Sun support because of the amount
of customization required.

First off, you will need a version of sendmail that has ldap capabilities
compiled into it. You can check this with:

/usr/lib/sendmail -d0.11 < /dev/null

Version 8.12.8+Sun
Compiled with: DNSMAP LDAPMAP LOG MAP_REGEX MATCHGECOS MILTER MIME7TO8

When you see LDAPMAP, you know that it will work. Solaris 7-9 should all
work. Patches are available for those that don't.

The Microsoft Active Directory is a different ldap server than your typical
ldap server, so you will want to browse the directory and learn more about
how it's designed. You will need to find or create a user that can browse
the Active Directory.

For the sake of simplicity, this example will use the Administrator userid
and his password to bind to the Active Directory server and find view its
contents.

For Solaris 8-9, if you have the SUNWlldap package installed, you can use
the ldapsearch command located /usr/bin. Run something like:

/usr/bin/ldapsearch -L -D "cn=Administrator, cn=Users, dc=domain, dc=com" \
-h domaincontroller.domain.com -b "dc=domain,dc=com" objectclass=* \
> /tmp/active_directory.ldif

It will ask you for a password. You want to input the Windows
Administrator's password there. You can open the /tmp/active_directory.ldif
file and read it and you can find a lot of the information in the directory
server.

If you do not have the ldapsearch command, while logged in as Administrator
on the Exchange server, you can achieve a similar result in Windows with

ldifde -f c:\temp\export.ldif -v

Upon knowing what's in the Active Directory, you can proceed to plug this
data into your sendmail configuration.

Because the Active Directory is a little different from your standard ldap
server, some hacks are required to make sendmail work.

You want to go into your /usr/lib/mail/hack directory. You can create it if
the directory isn't there. (The files are attached.) In there, you want to create a file called
AD_ldap_routing.m4 and inside of it have:

-----------------------------------------------------------------------------------------------------------
divert(0)
VERSIONID(`$Id: ldap_routing.m4 with MSFT Active Directory HACKS,v 8.8
2001/06/27 21:46:31 gshapiro Exp $')
divert(-1)

# Check first two arguments. If they aren't set, may need to warn in proto.m4
ifelse(len(X`'_ARG1_), `1', `define(`_LDAP_ROUTING_WARN_', `yes')')
ifelse(len(X`'_ARG2_), `1', `define(`_LDAP_ROUTING_WARN_', `yes')')

# Check for third argument to indicate how to deal with non-existant
# LDAP records
ifelse(len(X`'_ARG3_), `1', `define(`_LDAP_ROUTING_', `_PASS_THROUGH_')',
_ARG3_, `passthru', `define(`_LDAP_ROUTING_', `_PASS_THROUGH_')',
`define(`_LDAP_ROUTING_', `_MUST_EXIST_')')

# Check for fouth argument to indicate how to deal with +detail info
ifelse(len(X`'_ARG4_), `1', `',
_ARG4_, `strip', `define(`_LDAP_ROUTE_DETAIL_', `_STRIP_')',
_ARG4_, `preserve', `define(`_LDAP_ROUTE_DETAIL_', `_PRESERVE_')')

LOCAL_CONFIG
# LDAP routing maps
Kldapmh ifelse(len(X`'_ARG1_), `1',
<TAB> `ldap -1 -v msExchHomeServerName,msExchExpansionServerName -k (|(mail=%0)(proxyaddresses=smtp:%))',
<TAB> `_ARG1_')

Kldapmra ifelse(len(X`'_ARG2_), `1',
<TAB><TAB>`ldap -1 -v targetAddress -k (|(mail=%0)(proxyaddresses=smtp:%0))',
<TAB><TAB>`_ARG2_')

-------------------------------------------------------------------------------------------------------------
You will need to replace the <TAB> with real tabs.


The next step is to make the modifications to your .mc file.

The first feature we should add is a mailertable to tell sendmail where to
send mail with different ldapsearch results.

So we add the line:
FEATURE(`mailertable')

To add the ldap features into sendmail. Add the lines (of course, you put
in your domains):
HACK(`AD_ldap_routing')
LDAPROUTE_DOMAIN(`domain.com')dnl # what domain to do ldap lookups for.
LDAPROUTE_DOMAIN(`secondarydomain.com')dnl # alternate domain to do ldap lookups for.

You then need to specify your Active Directory settings (this all fits on
one line). You will also need to create the file /etc/mail/ldap.passwd. (We
will do this later)

define(`confLDAP_DEFAULT_SPEC',`-h domaincontroller.domain.com -M simple -d "cn=Administrator, cn=Users, dc=domain, dc=com" -P /etc/mail/ldap.passwd -p 389 -b "dc=domain, dc=com"')


We will now have to add some custom rulesets. You will again need to change
the <TAB> to real tabs.
There's also one line you need to change here.
R<> </ o=Domain / ou=First Administrative Group / cn=Configuration / cn=Servers / $+> <$+> <$+> <$*><TAB><TAB>$>LDAPMailertable <$1> $2
Make it match your organzation. You can find this by looking at your
active_directory.ldif file and seeing
the msExchHomeServerName attribute. Every user entry should have something
like:

msExchHomeServerName: /o=Domain/ou=First Administrative Group/cn=Configuration/cn=Servers/cn=domaincontroller

With that, you just strip off the last cn= and make spaces in between.

------------------------------------------------------------------------------------------------------


LOCAL_NET_CONFIG
R$* < @ $=m . > $*<TAB><TAB>$#esmtp $@ $2 $: $1 < @ $2 . > $3<TAB><TAB>internal addr delivered to host
R$* < @ $+ . $=m . > $*<TAB><TAB>$#esmtp $@ $2 . $3 $: $1 < @ $2 .$3 . > $4<TAB>internal w/host


# Begin custom LDAP rule set.
# the following lines are essentually copied from the proto.m4 file. They
are entered here to maintain the proper,
# original flow control but process the Active Directory response properly.
# pass names that still have a host to a smarthost (if defined)
R$* < @ $* > $*<TAB><TAB>$: $>MailerToTriple < $S > $1 < @ $2 > $3<TAB>glue on smarthost name


# deal with other remote names
R$* < @$* > $*<TAB><TAB>$#esmtp $@ $2 $: $1 < @ $2 > $3<TAB>user@host.domain


# handle locally delivered names
R$=L<TAB><TAB><TAB>$#local $: @ $1<TAB><TAB><TAB>special local names
R$+<TAB><TAB><TAB>$#local $: $1<TAB><TAB><TAB>regular local names


SLDAPExpand
#do the LDAP lookup for the Exchange Mail Host
R<$+><$+><$*><TAB>$: <$(ldapmra $2 $: $)> <$(ldapmh $2 $: $)> <$1> <$2> <$3>


# if mailRoutingAddress (targetAddress) and local or non-existant mailHost,
# return the new mailRoutingAddress
R<$+> <$=w> <$+> <$+> <$*><TAB>$@ $>Parse0 $>canonify $1
R<$+> <> <$+> <$+> <$*><TAB><TAB>$@ $>Parse0 $>canonify $1


# fix hostname in Mailertable, relay from there
R<$+> <$+> <$+> <$+> <$*><TAB>$>LDAPMailertable <$2> $>canonify $1

# if no mailRoutingAddress and local mailHost, return original address
R<> <$=w> <$+> <$+> <$*><TAB>$@ $2


# if no mailRoutingAddress and non-local mailHost,
# relay to mailHost (Exchange Server) with original address
# "de-AD" response at same time
# You'll need to do the query manually the find the proper stuff to pull out
R<> </ o=Domain / ou=First Administrative Group / cn=Configuration / cn=Servers / $+> <$+> <$+> <$*><TAB><TAB>$>LDAPMailertable <$1> $2


# if still no mailRoutingAddress and no mailHost,
# try @domain
R<> <> <$+> <$+ @ $+> <$*><TAB>$@ $>LDAPExpand <$1> <@ $3> <$4>


# if no mailRoutingAddress and no mailHost and this was a domain attempt,
# return the original address
R<> <> <$+> <@ $+> <$*><TAB><TAB>$@ $1
# End of custom LDAPExpand rule set
------------------------------------------------------------------------------------------------------

You now want to create your cf file.
/usr/ccs/bin/m4 ../m4/cf.m4 file.mc > file.cf

Now that we're done with the cf file, we need to supply the other files to
the configuration.
Create the ldap.passwd file:
echo "activedirectorypassword" > /etc/mail/ldap.passwd

Create the mailertable to tell sendmail where to send the mail. When we
stripped the last cn= off of the msExchHomeServerName, we will take that
and put it here. So my /etc/mail/mailertable will look like:
cn=domaincontroller esmtp:exchangeserver.domain.com

After you create this file, you will need to put it in the database for
sendmail to read it. Do this by running the command:
makemap -v hash /etc/mail/mailertable < /etc/mail/mailertable

You will also need to tell sendmail that you take mail for the domain as
well, so you want to put your domain in /etc/mail/local-host-names.
echo "domain.com" > /etc/mail/local-host-names

Now we will need to restart sendmail and test it. Run a command like this
for a user in the Active Directory:
/usr/lib/sendmail -bv alton@domain.com

You should see: alton@domain.com... deliverable: mailer esmtp, host
domaincontroller.domain.com, user alton@domain.com

If you run the same command on a user that's not in the Active Directory,
you should get:
/usr/lib/sendmail -bv other@domaincontroller.domain.com
other@domain.com... User unknown

Once you've got this, you're all set!

-------------------------------------------------------------------------------------------------------------
Some ideas on troubleshooting:

If you see
/usr/sbin/sendmail -bv alton@domain.com
alton@domain.com... deliverable: mailer relay, host cn=exchangeserver, user
alton@domain.com

You probably forgot the mailertable. The mailertable translates the cn=host
to the actual host and tells it which protocol to use to send the mail. In
our case, we use esmtp.



If you see something like this:
/usr/sbin/sendmail -bv alton@domain.com
alton@domain.com... deliverable: mailer esmtp, host domain.com., user
>/o=domain/ou=First.Administrative.Group/cn=Configuration/cn=Servers/cn=exchangeserver.alton@domain.com.alton@domain.com<

You have the wrong data in the area where it says:
# relay to mailHost (Exchange Server) with original address
# "de-AD" response at same time
in the sendmail.mc file.